5.2 图表决策分析方案
图表决策分析是将数据信息以图表的形式进行显示，通过图表中的图形，直观的对数据信息进行全面分析。
在用图表显示数据库中的数据时，一般都使用TDBChart组件，因为它可以直接与数据库相连接，TChart组件也可以获取数据库中的信息，并进行显示，只是其操作过程相对于TDBChart组件要麻烦的多。下面将主要以TDBChart组件为例，详细讲解图表的应用。
5.2.1 单图表分析方案
单图表是将图表与数据库相连接，并以单一的图表类型来显示数据内容。本方案是通过单图表对数据库中的数据进行统计分析。
1．方案分析
在制作管理系统时，有时需要对数据表中的数据进行统计，为了能让决策者更直观的了解数据的变动情况，可以用单图表来显示数据的统计结果。
单图表开发设计步骤：
（1）确定以图表显示的数据；
（2）对数据表中的信息进行分组、汇总等操作，以便图表进行显示；
（3）通过数据选择适合的图表类型；
（4）对图表进行相应的控制。
在制作单图表时，首先要确定对程序中的那一方面进行图表分析，然后对相应的数据表进行分析，使其可以根据需要生成图表，最后根据数据表中的信息对图表的显示情况进行相应的调整。下面给出单图表的制作流程图，如图5.11所示。
图5.11 单图表制作流程图
在直接生成图表时，主要有以下几个难点：
（1）如何使数据表中的数据符合图表的要求。
（2）当数据过多时，如何显示图表。
在设计图表时，要根据客户的需要将数据表中的数据进行分组、汇总等操作，判断当前数据适合于那一类型的图表，例如，要统计某年各月的销售量，可以使用条型图；要统计各地销售量占总销售量的百分比，可以使用饼型图。
制作图表时，要了解图表所对应数据表的信息，判断信息是不是可以与图表直接相关联，大多数的数据表都不能直接与图表相连接，必需对数据表的数据进行汇总、统计、分组等操作后才能在图表中显示所需要的数据。
2．实施过程
在开发销售管理系统时，经常需要对商品的日销售量、月销售量及年销售量等销售情况进行系统的分析，这样，可以很快的分析出哪个商品的销售量最好，或是哪种商品在某个时间段内的销售量最高。下面以统计某月的日销售量为例介绍单图表的制作过程。
l 方法一 用条型图显示日销售量
实例位置：光盘\mr\5\5.2\5.2.1\01
在制作日销售图表前，首先要对日销售信息进行查询，如图5.12所示，然后单击“图表”按钮时，将弹出“日销售额图表”窗体，如图5.13所示。
图5.12 产品销售表
图5.13 月销售图表
程序各窗体中相关组件说明，如表5.3所示。
表5.3 各窗体的相关组件
|
对象名 |
对象类型 |
属性 |
值 |
|
Module |
TDataModule |
Name |
Module |
|
ADOConnection1 |
TADOConnection |
ConnectionString |
连接数据库 |
|
ADOQuery1 |
TADOQuery |
Connection |
ADOConnection1 |
|
ADOQuery2 |
ADOConnection1 |
||
|
DataSource1 |
TDataSource |
DataSet |
ADOQuery1 |
|
DataSource2 |
ADOQuery2 |
||
|
Form1 |
TForm |
Caption |
产品销售表 |
|
Edit1 |
TEdit |
Text |
2006 |
|
Edit2 |
1 |
||
|
Button1 |
TButton |
Caption |
图表 |
|
Button2 |
查询 |
||
|
Form3 |
TForm |
Caption |
日销售图表 |
|
DBChart1 |
TDBChart1 |
将图表设置为条型图 |
使用TDataModule窗体来存放ADO组件，是为了方便调用TADOQuery组件，也可以重复调用同一个TADOQuery组件。
要制作某月的日销售额图表，首先要对数据库中的相应表格进行分析。Mr_Distribution数据库中的tb_Dist数据表，如图5.14所示。
图5.14 tb_Dist数据表中的信息
在图5.14所示的数据表中可以看出同一日期有多个记录，这样就不能以图表的形式来显示每月的日销售量，所以在“产品销售表”窗体中单击“图表”按钮时，应当在OnClick事件中对数据表tb_Dist中的TradeDate字段进行分组汇总，使TradeDate字段中的重复记录单一显示，并将TradeMoney字段进行求和。为了能够对指定年指定月份的日销售量进行显示，必须将数据表中的信息汇总前，对年份和月份进行设置。相关代码如下：
VYear := Trim(Edit1.Text); //年份
VMonth := Trim(Edit2.Text); //月份
if ((StrToInt(VYear)>1949) and ((StrToInt(VMonth)>0) and (StrToInt(VMonth)<13))) then
begin
with Module.ADOQuery2 do //用ADOQuery2将数据表中的数据进行汇总
begin
Close;
SQL.Clear;
SQL.Add('Select Day(TradeDate) as TDay,Sum(TradeMoney) TMoney');
SQL.Add('From tb_Dist Where (Month(TradeDate)='+VMonth+') And (Year(TradeDate)
='+VYear+')');
SQL.Add('Group BY TradeDate');
Open;
end;
//调用图表显示窗体
Application.CreateForm(TForm3,Form3);
Form3.ShowModal;
Form3.Free;
end;
用ADOQuery2组件对tb_Dist表中的TradeDate字段进行分组，并将TradeMoney字段进行求和，如图5.15所示。然后动态调用“日销售额图表”窗体。
图5.15 将tb_Dist表中的数据汇总成日销售量
在该窗体的OnCreate事件中对图表的显示样式进行设置。
在显示图表时，应在图表的顶部标题上对图表进行功能说明，在设置顶部标题时，首先要将原有的标题进行清除，然后在顶部标题上设置图表的相关功能说明，代码如下：
DBChart1.Title.Text.Clear;
DBChart1.Title.Text.Add('商品'+Form1.VYear+'年'+Form1.VMonth+'月份销售金额图表');
然后将ADOQuery2组件中已汇总的数据信息与图表相连接，TDBChart组件的XLabelsSource属性只能获取字符型的字段，TDBChart组件的YValues的ValueSource属性只能获取整型、浮点型，货币型的字段。代码如下：
DBChart1.Series[0].DataSource := Module.ADOQuery2;
DBChart1.Series[0].XLabelsSource := 'TDay';
DBChart1.Series[0].YValues.ValueSource := 'TMoney';
不同的公司所收取的货币类型可能不同，当Y轴为货币金额时，可以用图表的左标题在图表上显示货币类型。代码如下：
DBChart1.LeftAxis.Title.Caption := '货币类型：人民币';
DBChart1.LeftAxis.Title.Font.Color := clRed;
当指定的数据加载到图表时，应该对数据的多少进行控制，特别是条型图，如果数据过多时，无法将数据以条型图的方式清楚的显示在图表上，这时，就需要对图表进行分页显示，可以用TDBChart组件的MaxPointsPerPage属性来设置图表每页显示数据的最大个数。图表中的图例将显示加载后的所有记录，但是，因为图表的高度有限，不能在图例中显示全部，应用Legend的Visible属性将其隐藏，为了能让操作者看到每个数据块中的实际数值，应在数据块的标签中显示相应的值。代码如下：
DBChart1.MaxPointsPerPage := 7; //设置每页显示的最大数据个数
DBChart1.LeftAxis.Automatic := False; //使Y轴的最大值不自动设置
DBChart1.LeftAxis.Maximum := DBChart1.Series[0].MaxYValue+2000; //设置Y轴的最大值
DBChart1.Series[0].Marks.Style := smsValue; //设置标签的显示样式
if Module.ADOQuery2.recordcount>7 then //当数据超过一页时，在图表的下面显示如何进行翻页
begin
DBChart1.BottomAxis.Title.Caption := '用鼠标左键或右键进行上一页或下一页操作';
DBChart1.BottomAxis.Title.Font.Size := 8;
DBChart1.BottomAxis.Title.Font.Color := clBlue;
DBChart1.Legend.Visible := False; //隐藏图例
end
当图表分页后，应该对图表进行翻页操作，可以在TDBChart组件的OnClickBackground中用该组件的NextPage和PreviousPage属性进行图表翻页操作。代码如下：
procedure TForm3.DBChart1ClickBackground(Sender: TCustomChart;
Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
//用鼠标对图表进行翻页
if Button = mbLeft then
DBChart1.NextPage
else if Button = mbRight then
DBChart1.PreviousPage;
end;
在图表翻页的同时，应该在图表上显示当前页是第几页，可以在OnAfterDraw事件中用DBChart1组件的TextOut方法将Page属性所获取的当前页的数量重画到图表的指定位置上。代码如下：
procedure TForm3.DBChart1AfterDraw(Sender: TObject);
var
SPage : String;
begin
if Module.ADOQuery2.recordcount>7 then //在图表中显示当前是第几页
begin
DBChart1.Canvas.Font.Color := clBlue;
DBChart1.Canvas.Font.Size := 8;
DBChart1.Canvas.Brush.Style := bsclear;
SPage := '第'+IntToStr(DBChart1.Page)+'页';
DBChart1.Canvas.TextOut(10,10,SPage);
end;
end;
在对日销售量进行统计时，可以在图表的横坐标上，将周六周日的日期改成红色，以便操作者很容易的就能看出双休日的销售情况。可以在TDBChart组件的OnGetAxisLabel事件中进行设置。代码如下：
procedure TForm3.DBChart1GetAxisLabel(Sender: TChartAxis;
Series: TChartSeries; ValueIndex: Integer; var LabelText: String);
var
L_Date : TDateTime;
S : String;
begin
if (Sender = DBChart1.BottomAxis) then
begin
S := Form1.VYear+'-'+form1.VMonth+'-'+labelText;
if Pos('.',S)=0 then
begin
L_Date:=StrToDate(S);
if (DayOfWeek(L_Date)=1) or (DayOfWeek(L_Date)=7) then
DBChart1.BottomAxis.LabelsFont.Color:=clRed
else
DBChart1.BottomAxis.LabelsFont.Color:=clBlack;
end;
end;
end;
l 方法二 用折线图显示日销售的趋势图
实例位置：光盘\mr\5\5.2\5.2.1\02
用条型图显示日销售额时，只能对某月的日销量进行显示，无法显示某月的销售趋势，这时，可以用折线图来显示某月的日销售趋势，只需要将“日销售额图表”窗体中TDBChart组件的条型图删除，再添加一个折线图即可（将图形设置为平面效果），然后在“日销售额图表”窗体的OnCreate事件中添加如下代码，便可以制作一个日销售趋势图。
procedure TForm3.FormCreate(Sender: TObject);
begin
if Module.ADOQuery2.recordcount>0 then //图表与数据库相连接
begin
DBChart1.Title.Text.Clear;
DBChart1.Title.Text.Add('商品'+Form1.VYear+'年'+Form1.VMonth+'月份销售趋势图');
DBChart1.LeftAxis.Title.Caption := '货币类型：人民币';
DBChart1.LeftAxis.Title.Font.Color := clRed;
DBChart1.Series[0].DataSource := Module.ADOQuery2;
DBChart1.Series[0].XLabelsSource := 'TDay';
DBChart1.Series[0].YValues.ValueSource := 'TMoney';
DBChart1.Series[0].Marks.Style := smsValue; //设置标签的显示样式
DBChart1.LeftAxis.Automatic := False; //使Y轴的最大值不自动设置
DBChart1.LeftAxis.Maximum := DBChart1.Series[0].MaxYValue+1000; //设置Y轴的最大值
DBChart1.Legend.Visible := False;
end;
end;
运行结果如图5.16所示。
图5.16 日销售额图表
3．补充说明
用单图表显示数据时，也可以用饼型图来显示数据之间的比例关系，为了能使饼型图具有动态效果，可以通过鼠标单击实现饼型图的旋转效果。
当鼠标在饼型图上单击时，可以通过DBChart1组件的OnClickSeries事件来获取当前鼠标的Y轴坐值和饼型图表的旋转值。相关代码如下：
procedure TForm3.DBChart1ClickSeries(Sender: TCustomChart;
Series: TChartSeries; ValueIndex: Integer; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
begin
if button = mbLeft then
begin
CSVal := y; //保存鼠标单击时的Y轴坐标值
CSer := True; //标识
CSRot := Series1.RotationAngle; //保存当前饼型图的旋转度
end;
end;
饼型图的旋转度数在0~360之间，通过移动后的Y轴坐标与单击时Y轴坐标的差，再加上饼型图表的旋转度数，便可以使图表进行旋转，该操作可以在图表的On MouseMove事件中操作（鼠标移动事件）。相关代码如下：
procedure TForm3.DBChart1MouseMove(Sender: TObject; Shift: TShiftState; X,
Y: Integer);
begin
if CSer=True then //当为True时，图表将随鼠标的移动而旋转
begin
if Series1.RotationAngle>359 then
begin
CSRot := 1;
end;
if Series1.RotationAngle<1 then
begin
CSRot := 359;
end;
Series1.RotationAngle := abs(CSRot+(CSVal-y));
end;
end;
当鼠标松开时，使图表不再旋转。代码如下：
procedure TForm3.DBChart1MouseUp(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
begin
CSer := False;
end;
5.2.2 父子级关联图表分析方案
父子级关联图表是将大范围的数据显示在父级图表中，然后在子级图表中显示父级图表中某一部分范围的详细信息。本节将用父子级关联图表逐层深入的对数据进行分析。
1．方案分析
在对事物的发展趋势进行分析时，为了更详细的对事物进行分析，可以用父子关系对事物进行分级说明，也就是将事物分成几块，先对事物的大范围进行分析，然后，再对各范围的发展情况进行详细分析。
父子级关联图表开发设计步骤如下：
（1）连接数据库，在父级图表中显示数据；
（2）通过对父级图表的操作，生成子级图表；
（3）在生成子级图表时，对父级图表的相关数据块进行操作，以便说明。
在设置父子级关联图表时，首先要确定对哪些数据可以进行关联图表的操作，然后根据数据库中的相应数据生成父级图表，最后根据父级图表生成多个子级图表。下面给出父子级关联图表的制作流程图，如图5.17所示。
图5.17 父子级关联图表流程图
在制作父子级关联图表时，主要有以下几个难点：
（1）如何在窗体最大化时，按比例显示父子图表；
（2）如何在主表中动态显示当前子表显示的是哪一方面的数据；
（3）如何在主表中以颜色辨别对子表的操作；
（4）如何用一个图表动态显示多个子表数据。
在设计父子级关联图表时，一定要对实现目的以及数据库中的相关数据进行系统的分析，确定父级图表与子级图表的显示内容。在设计父级图表与子级图表的显示位置时，最好是左侧放置父级图表，右侧放置子级图表，当然，也可以根据具体的需要来任意设置父子级图表的位置。
在制作父子级关联图表时，当对数据库中的数据表进行相应的处理时，可以根据需要，将多个数据表通过相应的条件生成一个临时数据表，显示在图表中。当数据过多时，图表的X坐横轴就无法显示X轴的所有横坐标名称，这时，可以用分页的方试来显示数据，但有时，为了能够一次观察所有数据，可以将窗体最大化显示，但要注意父级图表与子级图表的显示比例。还需注意的是，当子级图是通过父级图表的相关操作而生成时，如何对父级图表的相关操作进行控制，并且在操作之后，如何在父级图表中显示，哪个是当前操作的，哪个是已操作完的，哪个是还未操作的。
2．实施过程
实例位置：光盘\mr\5\5.2\5.2.2\01
在开发销售管理系统时，可以根据商品的销售地区，对各个地区的商品销售情况作一个具体的分析，在这里，销售地区为父级图表，商品销售情况为子级图表。也可以对商品的销售领域进行具体的分析，下面以商品销售领域为例对父子关联图表进行详细的介绍。
首先要确定制作“商品销售领域综合分析图”的目的，一是要通过父级图表来显示某年各领域的销售情况，二是要通过子级图表来显示父级图表中某个销售领域的月销售量。然后根据以上目的来制作窗体的模式，在窗体中需要有两个图表，和一个用于选择年份的下拉列表框，具体效果如图5.18所示。
图5.18 销售领域综合分析图
程序各窗体中相关组件说明，如表5.4所示。
表5.4 各窗体的相关组件
|
对象名 |
对象类型 |
属性 |
值 |
|
DataModule1 |
TDataModule |
Name |
DataModule1 |
|
ADOConnection1 |
TADOConnection |
ConnectionString |
连接数据库 |
|
ADOQuery1 |
TADOQuery |
Connection |
ADOConnection1 |
|
ADOQuery2 |
ADOConnection1 |
||
|
DataSource1 |
TDataSource |
DataSet |
ADOQuery1 |
|
DataSource2 |
ADOQuery2 |
||
|
Form1 |
TForm |
Caption |
销售领域综合分析图 |
|
Panel1 |
TPanel |
Align |
alClient |
|
Panel2 |
alClient |
||
|
Panel4 |
alTop |
||
|
Panel5 |
alClient |
||
|
DBChart1（父级图表） |
TDBChart |
alClient |
|
|
Panel3 |
TPanel |
alRight |
|
|
DBChart2（子级图表） |
TDBChart |
alClient |
在统计年销售情况时可能会出现一条记录，而DBChart2组件的线型图不能显示单条记录，所以在DBChart2组件中添加线型图和条型图两种类型，并将线型图选为可用状态。
为了能够更好的了解窗体的设置情况，下面给出“对象浏览器”（Object TreeView）中对“销售领域综合分析图”窗体的设置，如图5.19所示。
图5.19 Form1窗体的对象浏览器
对商品销售领域进行综合分析时，首先要对数据库进行分析，然后找出相关联的数据表，进行操作。通过对数据库的分析可以确定，不论是父级图表“销售领域分析图”，还是子级图表“某领域的月销售情况”，都是由数据库MR_Distribution中的tb_ClientDist和tb_ClientInfo数据表共同组合而成的。tb_ClientInfo和tb_ClientDist数据表如图5.20、图5.21所示。
图5.20 tb_ClientInfo数据表
图5.21 tb_ClientDist数据表
下面对“销售领域综合分析图”窗体的制作进行全面的讲解。
父级图表是显示某年各领域的销售情况，那么，就应该在窗体创建时，将销售日期中的年份显示在一个下拉列表中，该操作主要是在窗体的OnCreate事件中用SQL语句将tb_ClientDist数据表中的销售日期中的年份提取出来，并将重复的年份去除。相关代码如下：
procedure TForm1.FormCreate(Sender: TObject);
begin
with DataModule1.ADOQuery1 do
begin
close;
SQL.Clear;
SQL.Add('select distinct year(Dist_Date) as D_Year from tb_ClientDist');
Open;
ComboBox1.Clear;
if RecordCount>0 then
while Not Eof do
begin
ComboBox1.Items.Add(FieldByName('D_Year').AsString);
Next;
end;
end;
end;
接下来就是要利用下拉列表中的年份来制作某年的销售领域分析图。首先，要通过年份将tb_ClientDist数据表中的指定年份的所有数据生成一个临时表##ppe，利用临时表##ppe中的Client_ID字段和tb_ClientInfo数据表中的Client_ID字段组合成一个新表，然后，将该表的以Client_Calling字段（销售领域）进行分组，并将Dist_Money字段（销售金额）进行求和。如图5.22所示。
图5.22 销售领域分析表
最后就是要将销售领域分析表与父级图表相连接，将数据表以图表的形式进行显示。相关代码如下：
procedure TForm1.ComboBox1Change(Sender: TObject);
begin
if ComboBox1.Text<>'' then
begin
DS := ComboBox1.Text;
Str := '';
Str := Str+'select * into ##ppe from tb_ClientDist';
Str := Str+' where year(Dist_Date)='+DS;
Str := Str+#13+'select sum(a.Dist_Money) as ''销售金额'',b.Client_Calling as ''
销售领域'' from ##ppe as a,tb_ClientInfo as b where a.Client_ID=b.Client_ID Group
BY b.Client_Calling';
Str := Str+#13+'drop table ##ppe';
XAxis := '销售领域';
YAxis := '销售金额';
Title := ComboBox1.Text+'年全年销售领域分析图';
//指定数据库组件与图表组件相连接
ChartSetup(Str, XAxis, YAxis, Title, DBChart1, DataModule1.ADOQuery1, 1);
end;
end;
在以上代码中，用自定义过程ChartSetup()将数据表与图表相连接，用该函数可以将不同的数据表与不同的图表相连接，当图表不符合数据显示时，将更换图表的类型。该过程的相关代码如下：
procedure TForm1.ChartSetup(S, Xval, Yval, Tit: String; DChart: TDBChart;
ADOChart: TADOQuery; p : Integer);
var
i,n:integer;
begin
n := 0;
with ADOChart do
begin
close;
SQL.Clear;
SQL.Add(S);
Open;
end;
if p=1 then
begin
SetLength(A_Color,ADOChart.RecordCount); //动态创建数组
for i:=0 to ADOChart.RecordCount-1 do //为数组设置初始值
begin
A_Color[i] := 'clred';
end;
DChart.Series[0].Marks.Style := smsValue;
end;
//在子级图表中，当数据记录为1时，用条型图显示
if ((ADOChart.RecordCount=1) and (P=0)) then
begin
DChart.Series[0].Active := False;
DChart.Series[1].Active := True;
n := 1;
end
else
//当子级图表的记录数大于1时，用线型图表显示数据
if ((ADOChart.RecordCount>1) and (P=0)) then
begin
DChart.Series[1].Active := False;
DChart.Series[0].Active := True;
n := 0;
end;
DChart.Series[n].DataSource := ADOChart;
DChart.Series[n].XLabelsSource := Xval;
DChart.Series[n].YValues.ValueSource := Yval;
DChart.Title.Text.Clear;
DChart.Title.Text.Add(Tit);
end;
ChartSetup()过程的参数说明如表5.5所示。
表5.5 ChartSetup()过程的参数说明
|
参数 |
说明 |
|
S |
SQL语句 |
|
Xval |
连接图表的X轴字段 |
|
Yval |
连接图表的Y轴字段 |
|
Tit |
图表的标题 |
|
DChart |
数据表连接的图表名称 |
|
ADOChart |
生成图表的ADO组件 |
|
p |
用于判断当前是父级图表，还是子级图表，1表示父级图表 |
动态数组A_Color是用来记录图表中数据块的颜色，通过该数组，可以使用黄色、绿色、红色来标记父级图表中的数据块哪个已被操作，哪个正在操作，哪个还未操作。
通过以上的操作，在父级图表中就会生成某年的销售领域分析图。接下来就要考虑，如何通过对父级图表的操作，生成子级图表？在TDBChart图表中有一个OnClickSeries事件，该事件在用鼠标单击或右击图表中的数据块时触发。可以利用该事件，在鼠标单击数据块时，在子级图表中生成相应的某领域月销售图表。并且在单击数据块时，先利用自定义函数SelectToColor()将上次单击的数据块颜色（绿色）改为以操作完的数据块颜色（黄色），再通过Series对象的ValueColor[ValueIndex]属性将当前操作的数据块颜色改为绿色，ValueIndex表示当前数据块的索引值。自定义过程SelectToColor()的相关代码如下：
procedure TForm1.SelectToColor(n : Integer;SColor : String;Col : TColor;Series : TChartSeries);
var
i : Integer;
begin
for i:=0 to n do
begin
if A_Color[i]=SColor then //A_Color是动态全局数组
Series.ValueColor[i]:= Col;
end;
end;
SelectToColor()过程的参数说明如表5.6所示。
表5.6 SelectToColor()函数的参数说明
|
参数 |
说明 |
|
n |
数据表中的记录个数 |
|
SColor |
原有的颜色 |
|
Col |
要更换的颜色 |
|
Series |
图表对象 |
然后用数组A_Color记录以改变的数据块颜色。再根据tb_ClientInfo数据表中的Client_ID字段和tb_ClientDist数据表的Client_ID字段，连接两个数据表，并以父级图表的年份和当前数据块的X轴名称为条件（也就是销售领域的名称），生成一个临时表##ppe。可以用如下代码来获取或修改当前数据块的X轴名称。
Series.XLabel[ValueIndex]
再将临时表##ppe以日期的月份进行分组，并对Dist_Money（销售金额）字段进行求和，生成某销售领域的月销售表，以电器业为例，如图5.23所示。
图5.23 电器业月销售表
最后就是利用自定义过程ChartSetup()将某领域的月销售表与子级图表相连接，将数据表以图表的形式进行显示。相关代码如下：
procedure TForm1.DBChart1ClickSeries(Sender: TCustomChart;
Series: TChartSeries; ValueIndex: Integer; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
begin
if button = mbLeft then
begin
//用鼠标单击图表中的数据块时，改变其数据块的颜色
SelectToColor(DataModule1.ADOQuery1.RecordCount-1,'clLime',clYellow,Series);
Series.ValueColor[ValueIndex]:= clLime;
A_Color[ValueIndex] := 'clLime';
Str := '';
Str := Str+'Select b.Dist_Money as Dist_Money,b.Dist_Date as Dist_Date,
a.Client_Calling as Client_Calling';
Str := Str+' into ##ppe';
Str := Str+' from tb_ClientInfo as a,tb_ClientDist as b';
Str := Str+' where b.Client_ID=a.Client_ID and year(b.Dist_Date)='+DS+' and
a.Client_Calling='+''''+Trim(Series.XLabel[ValueIndex])+'''';
Str := Str+#13+'select sum(Dist_Money) as ''月销售金额'',Month(Dist_Date) as
''月份''';
Str := Str+' from ##ppe';
Str := Str+' Group BY Month(Dist_Date)';
Str := Str+#13+'drop table ##ppe';
XAxis := '月份';
YAxis := '月销售金额';
Title := DS+'年'+Series.XLabel[ValueIndex]+'销售情况';
ChartSetup(Str, XAxis, YAxis, Title, DBChart2, DataModule1.ADOQuery2, 0);
End
//当单击鼠标右键时，使数据块的颜色恢复为红色
else if button = mbRight then
begin
Series.ValueColor[ValueIndex]:= clred;
A_Color[ValueIndex] := 'clred';
end;
CheckBox1.Checked := False;
end;
当父子级图表的数据量过多时，可以将窗体进行最大化显示，不过，在最大化显示的时候，应该控制父级图表和子级图表的显示比例，可以在窗体的OnResize事件中对图表的大小进行控制。相关代码如下：
procedure TForm1.FormResize(Sender: TObject);
begin
Form1.Panel3.Width := round(self.Width*0.4)
end;
3．补充说明
父级图表中的数据不但可以用条形图显示，也可以用柱形图或锥形图进行显示，修改的方法很简单，只是改变图表的相关属性即可。代码如下：
TBarSeries(chart1.Series[0]).BarStyle := bsCilinder;
BarStyle属性值有：bsArrow（箭头形）、bsCilinder（圆柱形）、bsEllipse（椭圆形）、bsInvPyramid（倒锥形）、bsPyramid（锥形）、bsRectangle（矩形）、bsRectGradient（渐变色矩形）。
5.2.3 并级关联图表分析方案
并级关联图表是对某一事物以多种状态进行分析，并以相应图表类型分别进行显示。本节就是利用并级关联图表对某一事物所关联的所有情况进行全面分析。
1．方案分析
在大部分的管理系统中，对事物的发展情况都是单一分析的，如进销存管理系统，一般只对商品的销售情况进行分析，并没有对商品供应商的往来账目进行分析。
并级关联图表的开发设计步骤如下：
（1）明确可以显示多个图表的关键值（也就是针对的某一事物）；
（2）通过关键值在数据库中查找多个相关联的数据结果；
（3）将数据结果与指定的图表相连接。
下面给出并级关联图表的制作流程图，如图5.24所示。
5.24 并级关联图表制作流程图
在生成并级关联图表时，主要有以下几个难点：
（1）如何用正确的数据分析某一事物；
（2）如何用一个自定义过程将多个数据与图表相连接；
在设置并级关联图表时，首先要明确对哪一事物作深入、全面的分析，然后通过数据库信息找出相关联的数据表，通过这些数据信息，对并级关联图表进行设置。
制作并级关联图表，实际上就是将某一方面的数据以图表的形式进行显示，但这些数据都是并列级的关系，它们谁也不包含谁，只是都与某一事物有一定的联系，通过这些数据，可以对该事物有一个全面的分析。
2．实施过程
在开发销售管理系统时，每个月都会对某一商品的销售情况进行分析，通过其分析结果，判断该商品在下个月的进货情况，或是通过该商品在各地的销售情况，来判断发货的多少。下面以某商品的日销售情况分析为例对并级关联图表进行详细的介绍。
实例位置：光盘\mr\5\5.2\5.2.3\01
在制作某商品的日销售情况分析图时，首先要在销售表（tb_ClientDist）和信息表（tb_ClientInfo）中对某年某月的商品销售情况进行查询，然后通过查询的结果，再生成相关的图表。这样就需要制作两个窗体，一个用于查询，一个用于显示图表，并在图表中分别显示某商品的月销售金额、各公司销售金额、月销售的最大金额/最小金额、各公司销售的最大/最小金额等情况。某单个商品的月销售情况分析表如图5.25所示，某个商品的综合分析图如图5.26所示。
图5.25 单个商品日分析表
图5.26 某商品的综合分析图
程序中各窗体中相关组件的说明，如表5.7所示。
表5.7 各窗体的相关组件
|
对象名 |
对象类型 |
属性 |
值 |
|
DataModule1 |
TDataModule |
Name |
DataModule1 |
|
ADOConnection1 |
TADOConnection |
ConnectionString |
连接数据库 |
|
ADOQuery1 |
TADOQuery |
Connection |
ADOConnection1 |
|
ADOQuery2 |
|||
|
ADOQuery3 |
|||
|
ADOQuery4 |
|||
|
ADOQuery5 |
|||
|
DataSource1 |
TDataSource |
DataSet |
ADOQuery1 |
|
Form1 |
TForm |
Caption |
单个商品月分析表 |
|
DBGrid1 |
TDBGrid |
Option.dgRowSelect |
True |
|
Form3 |
TForm |
Position |
poProportional |
|
Panel2 |
TPanel |
Align |
alTop |
|
DBChart1 |
TDBChart |
alClient |
|
|
DBChart2 |
TDBChart |
alRight |
|
|
Panel3 |
TPanel |
alClient |
|
|
DBChart3 |
TDBChart |
alRight |
|
|
DBChart4 |
TDBChart |
alClient |
在对单个商品进行分析的时候，首先要对数据库的数据表进行分析，在数据库中tb_ClientDist数据表对商品的销售金额及销售数量进行了记录。可以通过该表对商品的销售情况进行全面的分析。
下面对“某商品的月销售分析图”的制作过程进行全面的讲解。
首先要在“单个商品日分析表”窗体中，对商品某年、某月的销售信息进行查询，然后根据查询的结果，再生成相关的图表。在窗体创建时，首先要将tb_ClientDist数据表中的年份和商品名称在该窗体创建时分别存入到指定的下拉列表中，在tb_ClientDist数据表中年份或商品名称可能会重复，可以用SQL语句进行查询的时候，用distinct关键字将重复的字段删除，使下拉列表中只显示唯一的字段。相关代码如下：
procedure TForm1.FormCreate(Sender: TObject);
var
i : Integer;
begin
ComboBox3.Clear;
//销售的月份
for i:=1 to 12 do
ComboBox3.Items.Add(IntToStr(i));
//获取销售的年份
with DataModule1.ADOQuery1 do
begin
close;
SQL.Clear;
SQL.Add('select distinct year(Dist_Date) as D_Year from tb_ClientDist');
Open;
ComboBox2.Clear;
if RecordCount>0 then
while Not Eof do
begin
ComboBox2.Items.Add(FieldByName('D_Year').AsString);
Next;
end;
end;
//获取以销售的商品名称
with DataModule1.ADOQuery1 do
begin
close;
SQL.Clear;
SQL.Add('select distinct Dist_Name from tb_ClientDist');
Open;
ComboBox1.Clear;
if RecordCount>0 then
while Not Eof do
begin
ComboBox1.Items.Add(FieldByName('Dist_Name').AsString);
Next;
end;
end;
ComboBox1.OnChange(Sender);
end;
将信息存入到下拉列表之后，就需要通过下列表中的字段对数据表中的数据进行查询（本实例中要查询的表格为tb_ClientDist和tb_ClientDist、tb_ClientInfo的综合表），当改变某一下拉列表中的信息时，可以在下拉列表的OnChange事件中对信息进行查询，并在DBGrid1组件中进行显示。相关代码如下：
procedure TForm1.ComboBox1Change(Sender: TObject);
begin
//获取tb_ClientDist表的查询结果
Inq := 'select * from tb_ClientDist';
Inq1:='';
Inq2:='';
Inq3:='';
SQLSentence := Inq;
if ComboBox1.Text<>'' then
Inq1 := 'Dist_Name='+''''+Trim(ComboBox1.Text)+'''';
if ComboBox2.Text<>'' then
Inq2 := 'year(Dist_Date)='+Trim(ComboBox2.Text);
if ComboBox3.Text<>'' then
Inq3 := 'Month(Dist_Date)='+Trim(ComboBox3.Text);
SQLByeLaw := DistInquire(Inq,Inq1,Inq2,Inq3,0,DataModule1.ADOQuery1,
DataModule1.DataSource1,DBGrid1);
//对tb_ClientDist和tb_ClientInfo的综合表进行查询
Inq := 'select a.Dist_ID Dist_ID,b.Client_Name Client_Name,a.Dist_Name Dist_Name,
a.Dist_Count Dist_Count,a.Unit Unit,a.Unit_Price Unit_Price,a.Dist_Money Dist_Money,
a.Dist_Date Dist_Date from tb_ClientDist a, tb_ClientInfo b where a.Client_ID
=b.Client_ID';
Inq1:='';
Inq2:='';
Inq3:='';
SQLSentence := Inq;
if ComboBox1.Text<>'' then
Inq1 := 'a.Dist_Name='+''''+Trim(ComboBox1.Text)+'''';
if ComboBox2.Text<>'' then
Inq2 := 'year(a.Dist_Date)='+Trim(ComboBox2.Text);
if ComboBox3.Text<>'' then
Inq3 := 'Month(a.Dist_Date)='+Trim(ComboBox3.Text);
DistInquire(Inq,Inq1,Inq2,Inq3,1,DataModule1.ADOQuery1,
DataModule1.DataSource1,DBGrid1);
end;
以上代码只是将下拉列表中的字段以SQL语句的查询条件进行保存，然后根据自定义过程DistInquire()对相应数据表中的数据进行查询。该过程是将数据的查询条件与指定的SQL语句相连接，用TADOQuery类型的组件进行查询，并通过TDBGrid类型的组件进行显示。其相关代码如下：
function TForm1.DistInquire(Str, S1, S2, S3: String; Sign :Integer; ADOQ: TADOQuery;
DS: TDataSource; DBG: TDBGrid):String;
begin
if ((S1<>'') or (S2<>'') or (S3<>'')) then
begin
if Sign=1 then
Str := Str+' and '
else
Str := Str+' where ';
if S1<>'' then
begin
Str := Str+S1;
if ((S2<>'') or (S3<>'')) then
Str := Str+' and ';
end;
if S2<>'' then
begin
Str := Str+S2;
if ((S1<>'') or (S3<>'')) then
Str := Str+' and ';
end;
if S3<>'' then
begin
Str := Str+S3;
if ((S2<>'') or (S1<>'')) then
Str := Str+' and ';
end;
if (Trim(Copy(Str,Length(Str)-4,4))='and') then
Str := Copy(Str,1,Length(Str)-4);
end;
with ADOQ do
begin
Close;
SQL.Clear;
SQL.Add(Str);
open;
end;
DBG.DataSource := DS;
result := Str;
end;
DistInquire()过程的参数说明如表5.8所示。
表5.8 SelectToColor()函数的参数说明
|
参数 |
说明 |
|
Str |
字符串类型，用于记录SQL语句 |
|
S1 |
查询条件 |
|
S2 |
查询条件 |
|
S3 |
查询条件 |
|
Sign |
用于判断SQL语句是否有查询条件，如果值为0，表示无查询条件，为1，有查询条件 |
|
ADOQ |
TADOQuery类型，用于对数据表进行查询 |
|
DS |
TDataSource类型，用于连接数据源和数据表 |
|
DBG |
TDBGrid类型，用于显示数据信息 |
对商品的数据进行查询之后，就可以调用图表窗体对该商品进行分析，在调用图表窗体的同时，应该将当前记录以标题的形式在调用窗体的标题栏中进行显示。相关代码如下：
procedure TForm1.BitBtn1Click(Sender: TObject);
begin
if ((ComboBox1.Text<>'') and (ComboBox2.Text<>'') and (ComboBox3.Text<>'')) then
begin
Condition := 'where Dist_Name='+''''+Trim(ComboBox1.Text)+''''+' and
year(Dist_Date)='+Trim(ComboBox2.Text)+' and Month(Dist_Date)='+Trim
(ComboBox3.Text);
Titl := ComboBox2.Text+'年'+ComboBox3.Text+'月份'+ComboBox1.Text+'商品的';
Application.CreateForm(TForm3,Form3);
Form3.Caption := Titl+'分析图';
Form3.ShowModal;
Form3.Free;
end
else
showmessage('请选择全部的条件');
end;
下面对“商品的销售分析图”窗体的制作过程进行讲解。
首先要对某商品的月销售金额、各公司销售金额、月销售的最大金额/最小金额、各公司销售的最大/最小金额四个图表进行分析，月销售金额和各公司销售金额应该以线型图表进行显示，当商品的销售数量只有一个时，线型图表无法显示，只能用条型图表进行显示，这时，就应该在图表中创建线型图和条型图两种，根据数量的多少来判断用哪一类型的图表，然后再用图表显示商品的相关信息，以下过程，应该在窗体的OnCreate事件中执行。相关代码如下：
procedure TForm3.FormCreate(Sender: TObject);
var
Sele : String;
begin
if DataModule1.ADOQuery1.RecordCount<=1 then
begin
DBChart1.Series[0].Active := False;
DBChart1.Series[1].Active := True;
DBChart4.Series[0].Active := False;
DBChart4.Series[1].Active := True;
Mark := 1;
end
else
begin
DBChart1.Series[0].Active := True;
DBChart1.Series[1].Active := False;
DBChart4.Series[0].Active := True;
DBChart4.Series[1].Active := False;
Mark := 0;
end;
//设置图表相对应的SQL语句
SQLSentence('Day(Dist_Date)','销售日期','Dist_Money','销售金额',form1.SQLByeLaw,
form1.Titl+'销售金额','',0,Mark,DataModule1.ADOQuery2,DBChart1);
Sele := '('+form1.SQLSentence+') f';
SQLSentence('Dist_Date','销售日期','Dist_Money','销售金额',form1.Condition,
form1.Titl+'销售最大金额/最小金额','tb_ClientDist',1,0,DataModule1.ADOQuery4,
DBChart2);
SQLSentence('Client_Name','公司名称','sum(Dist_Money)','销售金额',form1.Condition,
form1.Titl+'各公司销售情况',Sele,2,Mark,DataModule1.ADOQuery5,DBChart4);
SQLSentence('Client_Name','公司名称','sum(Dist_Money)','销售金额',form1.Condition,
form1.Titl+'公司最大/最小金额',Sele,3,0,DataModule1.ADOQuery3,DBChart3);
end;
自定义过程SQLSentence()，主要是将生成图表的SQL语句进行组合，并将一些重复的语句进行简化。相关代码如下：
procedure TForm3.SQLSentence(CField1, CAlias1, FField2, FAlias2, Condition,
Caption, TableName: String; Sign,Odd : Integer; ADOChart: TADOQuery; DChart: TDBChart);
var
S,X,Y,T,LS : String;
begin
if (Sign=1) or (Sign=3) then
begin
if Sign=1 then
begin
S := 'Select '+CField1+' as '+''''+CAlias1+''''+','+FField2+' as '+''''+
FAlias2+''''+' From (';
S := S+' select top 1 * from '+TableName+' ';
S := S+Condition;
LS := S;
end;
if Sign=3 then
begin
S := 'Select * From (select top 1 * from (';
S := S+'Select '+CField1+' as '+''''+CAlias1+''''+','+FField2+' as '+''''+
FAlias2+''''+' from '+TableName+' ';
S := S+Condition+' Group By '+CField1+') d';
LS := S;
FField2 := FAlias2;
end;
if Sign=3 then
S := S+' order by '+FAlias2+') a'
else
S := S+' order by '+FField2+') a';
S := S+#13+'union';
S := S+#13+LS;
if Sign=3 then
S := S+' order by '+FAlias2+' desc) a'
else
S := S+' order by '+FField2+' desc) a';
end;
if Sign=0 then
S := 'Select '+CField1+' as '+''''+CAlias1+''''+','+FField2+' as '+''''+
FAlias2+''''+' from ('+Condition+') a';
if Sign=2 then
begin
S := 'Select '+CField1+' as '+''''+CAlias1+''''+','+FField2+' as '+''''+
FAlias2+''''+' from '+TableName+' ';
S := S+Condition+' Group By '+CField1;
end;
X := CAlias1;
Y := FAlias2;
T := Caption;
//将数据与指定的图表相连接
ConnectChart(S, X, Y, T, ADOChart, DChart, Sign, Odd);
end;
DistInquire()过程的参数说明如表5.9所示。
表5.9 DistInquire ()函数的参数说明
|
参数 |
说明 |
|
CField1 |
数据表中的字段，相对于图表的X轴 |
|
CAlias1 |
CField1字段的别名 |
|
CField2 |
数据表中的字段，相对于图表的Y轴 |
|
CAlias2 |
CField2字段的别名 |
|
Condition |
用于记录SQL语句中的相关信息 |
|
Caption |
记录图表中的标题信息 |
|
TableName |
记录当前操作数据表的表名 |
|
Sign |
标记，用于判断执行那一段SQL语句 |
|
Odd |
标记，用于判断图表的显示样式 |
|
ADOChart |
TADOQuery类型，用于对数据表进行查询 |
|
DChart |
TDBChart类型，用于将查询后的数据显示在指定的图表上 |
在以下代码中，用到了自定义过程ConnectChart()，该过程是将指定的SQL语句与相对应的图表进行连接。相关代码如下：
procedure TForm3.ConnectChart(S, Xval, Yval, Tit : String; ADOQ: TADOQuery;
DChart: TDBChart; p,n : Integer);
begin
with ADOQ do
begin
Close;
SQL.Clear;
SQL.Add(S);
Open;
end;
DChart.Series[n].DataSource := ADOQ;
DChart.Series[n].XLabelsSource := Xval;
DChart.Series[n].YValues.ValueSource := Yval;
DChart.Title.Text.Clear;
if ADOQ.RecordCount=0 then
Tit := '无商品记录';
DChart.Title.Text.Add(Tit);
if ADOQ.RecordCount>10 then
DChart.Legend.Visible := False;
if ((p=1) or (p=3) or (n=1)) then
begin
DChart.Series[n].Marks.Style := smsValue;
DChart.Legend.Visible := False;
end;
end;
ConnectChart()过程的参数说明如表5.10所示。
表5.10 ConnectChart()函数的参数说明
|
参数 |
说明 |
|
S |
字符型，用于保存SQL语句 |
|
Xval |
数据表中的字段，用于连接图表的X轴 |
|
Yval |
数据表中的字段，用于连接图表的Y轴 |
|
Tit |
字符型，用于记录图表的标题 |
|
ADOQ |
TADOQuery类型，用于对数据表进行查询 |
|
DChart |
TDBChart类型，用于将数据显示在指定的图表上 |
|
p |
标记，用于判断图表的显示样式 |
|
n |
标记，用于判断图表的显示样式 |
通过以上代码，就可以实现对单个商品的月销售分析，但是，在数据过多时，无法在图表中进行完整的显示，这时，可以将窗体进行最大化，为了能够在窗体最大化时，让图表按原来的比例进行显示，应该在窗体的OnResize事件中对图表的大小进行设置。相关代码如下：
procedure TForm3.FormResize(Sender: TObject);
begin
Panel2.Height := self.Height div 2;
DBChart2.Width := round(self.Width*0.38);
DBChart3.Width := round(self.Width*0.38);
end;
3．补充说明
在图表中显示数据时，为了能更好的显示数据之间的数量关系，可以在查询数据时，对数据进行排序，可以用SQL语句Order By来实现。
在用线形图显示数据时，为了能够更清楚的看到各个数据之间的变化，可以将线形图表中的数据线颜色以随机颜色进行显示。代码如下：
DBChart1.Series[0].ColorEachPoint := True;
5.2.4 数据对比图表分析方案
数据对比图表是在一定时间内，对相关事物进行比效，以便对事物间的发展关系进行分析，从而可以更快的判断出各事物的发展趋势。本节将各个时间段的数据信息以相同的图表类型进行显示，并将各类型的数据信息进行组合，以实现对比分析的效果。
1．方案分析
当对多个时间段的数据信息进行分析时，有时需要将多个时间段的信息进行对比分析。那么，就需要将各时间段的信息在一个图表中进行显示。这时，可以将多个类型的图表进行组合，来�